Category Archives: 433

Détecteur de choc & TX 433Mhz pilotés avec le Microcontrôleur AVR ATTINY85

Circuit monté sur breadboard

Circuit monté sur breadboard

Avec la mise en veille (SLEEP_MODE_PWR_DOWN) et l’utilisation des interruptions , le circuit au repos ne consomme que 4µA avec un microcontrôleur Attiny85 (1€89 sur ebay) . J’alimente le circuit avec une pile bouton CR2032 3V achetée chez Ikea par lot de 8 pour quelques €uros. Le circuit devrait tourner beaucoup plus d’une année. 20160122_104647

300px-KY002

Détecteur de choc

A chaque détection de choc, le transmetteur 433Mhz émet un signal RF qui est reconnu par une Zibase en périphérique E10. Ce signal RF est défini dans le code de l’Attiny85 à la ligne n°46 (mySwitch.switchOn(‘e’, 3,2); // Test Zibase signal id E10) Dans mon circuit, je n’alimente pas le détecteur  en 5V, mais je l’utilise comme simple contacteur qui déclenche une interruption lorsqu’il y a détection de choc ( voir code: digitalWrite(WAKEUP_PIN, HIGH); // Activate internal pullup resistor ).

sku_334387_1
Tx 433MHz

Le détecteur,  grâce à la zibase, est intégré au système d’alarme . Présentement, il m’est inutile de monter une antenne de 17,3cm. En effet le signal est suffisamment puissant pour être reçu 5/5 à environ 7 mètres du récepteur RF ( la zibase, ou mon stick RTL-SDR connecté à un Raspberry Pi).

Détection niveau batterie faible

Un niveau de batterie faible est indiqué par la led qui flashe toutes les 8 secondes. Pour la détection de niveau de batterie faible, je me suis inspiré du post de Nick Gammon http://www.gammon.com.au/power

uint16_t readVcc(void) {
  uint16_t result;
  // Read 1.1V reference against Vcc
  ADMUX = (0<<REFS0) | (12<<MUX0);
  delay(2); // Wait for Vref to settle
  ADCSRA |= (1<<ADSC); // Convert
  while (bit_is_set(ADCSRA,ADSC));
  result = ADCW;
  return 1018500L / result; // Back-calculate AVcc in mV
}

Consommation du circuit avec un Arduino et Attiny85

sku_334387_1

TX 433.92MHz

  1. Attiny85: 4µA 
  2. Avec un arduino Nano : 43mA !!!
  3. Arduino M.J duino uno: 6,5mA
  4. Arduino XDRduino: 25mA
  5. Arduino Mini Pro: 3,5 mA . En ôtant la LED (on) et le régulateur de tension 5V, on pourrait tomber à moins d’1mA

RF Shock sensor Sketch_bb

Le script pour Attiny85

Pour programmer l’Attiny85 à l’aide d’un arduino, je me suis inspiré du post d’Erwan http://labalec.fr/erwan/?p=1508. Éventuellement, ne pas oublier de graver la séquence d’initialisation (bootloader) de l’Attiny85.

// https://blog.onlinux.fr/
//
//
//                           +-\/-+
//          Ain0 (D 5) PB5  1|    |8  Vcc
//          Ain3 (D 3) PB3  2|    |7  PB2 (D 2) Ain1 -
// LED +pin Ain2 (D 4) PB4  3|    |6  PB1 (D 1) pwm1 - Shock sensor pin
//                     GND  4|    |5  PB0 (D 0) pwm0 - RF433 tx pin
// 
// **** INCLUDES *****
#include <avr/sleep.h>
#include <avr/wdt.h>
#include <RCSwitch.h>

#ifndef cbi
#define cbi(sfr, bit) (_SFR_BYTE(sfr) &= ~_BV(bit))
#endif
#ifndef sbi
#define sbi(sfr, bit) (_SFR_BYTE(sfr) |= _BV(bit))
#endif

#define LOW_BATTERY_LEVEL 2500 //mV. Led will flash if battery level is lower than this value
#define WDT_COUNT  225  // wdt is set to 8s, 8x225=1800 seconds = 30 minutes

volatile boolean f_wdt = 0;
volatile byte count = WDT_COUNT;
volatile boolean f_int = 0;
volatile boolean lowBattery = 0;
volatile boolean switchState = HIGH;

const byte TX_PIN   = PB0;  // Pin number for the 433mhz OOK transmitter
const byte LED_PIN  = PB4;
const byte WAKEUP_PIN = PB1;  // Use pin 1 as wake up pin

RCSwitch mySwitch = RCSwitch();

/******************************************************************/
 
void setup()
{
  setup_watchdog(9);
  pinMode(TX_PIN, OUTPUT);
  pinMode(WAKEUP_PIN, INPUT);        // Set the pin to input
  digitalWrite(WAKEUP_PIN, HIGH);    // Activate internal pullup resistor  
  mySwitch.enableTransmit(TX_PIN);
  
  mySwitch.switchOn('e', 3,2);      // Test Zibase signal id E10
  
  lowBattery =  !(readVcc() >= LOW_BATTERY_LEVEL); // Initialize battery level value
  
  PCMSK  |= bit (PCINT1);  // set pin change interrupt PB1
  GIFR   |= bit (PCIF);    // clear any outstanding interrupts
  GIMSK  |= bit (PCIE);    // enable pin change interrupts  
  sei();         
}


// set system into the sleep state 
// system wakes up when watchdog is timed out
void system_sleep() {
  cbi(ADCSRA,ADEN);                    // switch Analog to Digitalconverter OFF

  set_sleep_mode(SLEEP_MODE_PWR_DOWN); // sleep mode is set here
  sleep_enable();

  sleep_mode();                        // System sleeps here

  sleep_disable();                     // System continues execution here when watchdog timed out 
  sbi(ADCSRA,ADEN);                    // switch Analog to Digitalconverter ON
}

// 0=16ms, 1=32ms,2=64ms,3=128ms,4=250ms,5=500ms
// 6=1 sec,7=2 sec, 8=4 sec, 9=8sec
void setup_watchdog(int ii) {

  byte bb;
  int ww;
  if (ii > 9 ) ii=9;
  bb=ii & 7;
  if (ii > 7) bb|= (1<<5);
  bb|= (1<<WDCE);
  ww=bb;

  MCUSR &= ~(1<<WDRF);
  // start timed sequence
  WDTCR |= (1<<WDCE) | (1<<WDE);   
  // set new watchdog timeout value   
  WDTCR = bb;   WDTCR |= _BV(WDIE); 
}
    
// Watchdog Interrupt Service / is executed when watchdog timed out 
ISR(WDT_vect) {   
  if (count >= WDT_COUNT) {
   f_wdt=true;  // set WDTl flag
   count=0;
  }
  count++;
} 

ISR (PCINT0_vect){
  f_int=true; // set INT flag
}
 
void loop()
{
  system_sleep();
  
  if (lowBattery)        // lowBattery is at setup().
    lowBatteryWarning(); // Flash for 1ms every 8s http://www.gammon.com.au/power
  
  
  if (f_int) {
    blink(2);
    cli();
    mySwitch.switchOn('e', 3,2);      // Zibase signal id E10
    f_int=false;  // Reset INT Flag
    sei();
  } 
  else if ( f_wdt ) {
    blink(5);
    cli(); // disable interrupts
    lowBattery = !(readVcc() >= LOW_BATTERY_LEVEL);
    f_wdt=false; // reset WDT Flag
    sei(); // enable interrupts
  }
    
}


void blink(int ii) {
  pinMode(LED_PIN, OUTPUT);
  for (byte i = ii ;  i > 0 ; i--){
     digitalWrite(LED_PIN, HIGH);
     delay(50);
     digitalWrite(LED_PIN, LOW); 
     delay(50);
  }
  
  pinMode(LED_PIN, INPUT); // reduce power
}

void lowBatteryWarning () {
  pinMode(LED_PIN, OUTPUT);
  digitalWrite (LED_PIN, HIGH);  
  delay (1);       // mS        
  digitalWrite (LED_PIN, LOW);    
  //delay (999); 
  pinMode(LED_PIN, INPUT); // reduce power  
}

uint16_t readVcc(void) {
  uint16_t result;
  // Read 1.1V reference against Vcc
  ADMUX = (0<<REFS0) | (12<<MUX0);
  delay(2); // Wait for Vref to settle
  ADCSRA |= (1<<ADSC); // Convert
  while (bit_is_set(ADCSRA,ADSC));
  result = ADCW;
  return 1018500L / result; // Back-calculate AVcc in mV
}

Et la suite…

Le circuit pourrait ếtre encore plus miniaturisé en se passant du breadboard.
Maintenant il ne reste qu’à trouver un joli boîtier pour cacher toute l’électronique.
Malheureusement je n’ai pas d’imprimante 3D!

20160122_121130_cut

Le détecteur de choc et en haut le détecteur d’ouverture

Si vous avez des idées pour une solution esthétique, n’hésitez pas!

Détecteur de mouvement PIR & TX 433Mhz pilotés avec le Microcontrôleur AVR ATTINY85

PIR Atinny85 Sketch_bb

 

pir

Détecteur de mouvement PIR

Avec la mise en veille (SLEEP_MODE_PWR_DOWN) et l’utilisation des interruptions (INT0) , le circuit au repos ne consomme que 30µA avec un Attiny85 (1€89 sur ebay) . Avec le jeu de piles AAA ( en fait je n’en ai

Attiny85

Attiny85

mis que 3 en série), le circuit devrait tourner plus d’une année.

A chaque détection de mouvement, le transmetteur 433Mhz envoie une trame qui est reconnue par une Zibase en périphérique B15.

Le détecteur,  grâce à la zibase, est intégré au système d’alarme et,  avec  un scénario, il permet de gérer la lumière de la cuisine.

Consommation avec un Arduino

sku_334387_1

TX 433.92MHz

  1. Avec un arduino Nano : 43mA !!!
  2. Arduino M.J duino uno: 6,5mA
  3. Arduino XDRduino: 25mA
  4. Arduino Mini Pro: 3,5 mA . En ôtant la LED (on) et le régulateur de tension 5V, on pourrait tomber à moins d’1mA, mais ce sera toujours bien plus qu’un circuit à base de l’Attiny85. Il faudra que j’essaie!

Le script pour Attiny85

Pour programmer l’Attiny85 à l’aide d’un arduino, je me suis inspiré du post d’Erwan http://labalec.fr/erwan/?p=1508. Éventuellement, ne pas oublier de graver la séquence d’initialisation (bootloader) de l’Attiny85.

// **** INCLUDES *****
#include <avr/sleep.h>
#include <avr/interrupt.h>
#include  

#ifndef cbi
#define cbi(sfr, bit) (_SFR_BYTE(sfr) &= ~_BV(bit))
#endif
#ifndef sbi
#define sbi(sfr, bit) (_SFR_BYTE(sfr) |= _BV(bit))
#endif


// Use pin 0 as wake up pin
const int wakeUpPin = 0;
volatile int ledState = LOW;
#define tx 1 // Pin number for the 433mhz OOK transmitter
#define pinLed 4
RCSwitch mySwitch = RCSwitch();

// set system into the sleep state 
void system_sleep() {
 cbi(ADCSRA,ADEN); // switch Analog to Digitalconverter OFF
 set_sleep_mode(SLEEP_MODE_PWR_DOWN); // sleep mode is set here
 sleep_enable();
 sleep_mode(); // System sleeps here

 sleep_disable(); // System continues here 
 sbi(ADCSRA,ADEN); // switch Analog to Digitalconverter ON
}

void setup()
{
 pinMode(wakeUpPin, INPUT); 
 pinMode(pinLed, OUTPUT); 
 mySwitch.enableTransmit(tx);
 
 PCMSK |= bit (PCINT0); 
 GIFR |= bit (PCIF); // clear any outstanding interrupts
 GIMSK |= bit (PCIE); // enable pin change interrupts 
 sei();
}

ISR (PCINT0_vect) 
{
 ledState = digitalRead(0);
}

void loop() 
{

 system_sleep();

 if (ledState) {
   digitalWrite(pinLed, ledState);
   mySwitch.switchOn("01111", "00010"); // ZIBASE => B15 
   delay(500);
   digitalWrite(pinLed, !ledState);
 }

}

 

Le script pour Arduino

// **** INCLUDES *****
#include "LowPower.h"
#include  

// Use pin 2 as wake up pin
const int wakeUpPin = 2;
volatile int ledState = LOW;
#define tx 4 // Pin number for the 433mhz OOK transmitter

RCSwitch mySwitch = RCSwitch();

void wakeUp()
{
 // Just a handler for the pin interrupt.
 //Serial.println("RISING on D2");
 ledState = !ledState; 
 digitalWrite(13, ledState); 
 
}

void setup()
{
 // Configure wake up pin as input.
 // This will consumes few µA of current.
 pinMode(wakeUpPin, INPUT); 
 pinMode(13, OUTPUT); 
 Serial.begin(9600); // use the serial port
 mySwitch.enableTransmit(tx);
 
}

void loop() 
{
 attachInterrupt(0, wakeUp, CHANGE);
 // Enter power down state with ADC and BOD module disabled.
 // Wake up when pin changes
 LowPower.powerDown(SLEEP_FOREVER, ADC_OFF, BOD_OFF); 

 
 // Disable external pin interrupt on wake up pin.
 detachInterrupt(0); 
 
 // Do something here
 // Example: Read sensor, data logging, data transmission.
 if (ledState) {
   Serial.println("RISING on D2");
   mySwitch.switchOn("01111", "00010"); // ZIBASE = A15 ?? 00 15 11 
 }
 else {
   Serial.println("FALLING on D2");
 }
 delay(500);

}

Réception 433.92MHz du compteur de consommation électrique OWL Micro+ ou CM180 avec un dongle Realtek RTL2832 DVB.

 

20150127

rtl-sdr dongle + Owl Micro+ CM180

Le programme rtl_433 permet de convertir un dongle RTL2832 initialement prévu pour la réception TV TNT hd en  récepteur 433,92MHz.  Ce dongle est disponible à l’achat sur internet pour une vingtaine d’euros. (Une recherche google sur  “sdr rtl” vous fournira une multitude de renseignements ainsi que des liens sur des boutiques de vente en  ligne proposant ce dongle).

L’acronyme SDR signifie Software Defined Radio, et RTL c’est la puce (RTL2832) qui équipe le dongle .

J’ai acheté le mien chez Passion Radio Shop

Tout nouveau possesseur d’un de ces dongles miraculeux, j’ai ajouté rapidement le support du OWL micro+ au programme rtl_433.  Le projet initial rtl_433 peut être téléchargé ici: https://github.com/merbanan/rtl_433 (depuis février 2015 mes modifications y ont été intégrées. Désormais le programme rtl_433 reconnaît  les trames envoyées par OWL CMR180)

Je l’ai adapté afin de supporter le transmetteur OWL CMR180 qui accompagne le récepteur OWL CM180. Vous pouvez télécharger un fichier zip disponible  sur le repository github https://github.com/onlinux/rtl_433 ou bien cloner le projet en local sur votre pc

git clone https://github.com/onlinux/rtl_433.git
cd rtl_433/
mkdir build
cd build
cmake ../
make
make install

20150127-zoom

@I7:~/rtl_433/build$ rtl_433 
Registering protocol[01] Rubicson Temperature Sensor 
Registering protocol[02] Prologue Temperature Sensor 
Registering protocol[03] Silvercrest Remote Control 
Registering protocol[04] ELV EM 1000 
Registering protocol[05] ELV WS 2000 
Registering protocol[06] Waveman Switch Transmitter 
Registering protocol[07] Steffen Switch Transmitter
Registering protocol[08] Acurite 5n1 Weather Station
Registering protocol[09] Acurite Temperature and Humidity Sensor
Registering protocol[10] Acurite 896 Rain Gauge
Registering protocol[11] LaCrosse TX Temperature / Humidity Sensor
Registering protocol[12] Oregon Scientific Weather Sensor
Registering protocol[13] KlikAanKlikUit Wireless Switch
Registering protocol[14] AlectoV1 Weather Sensor
Registering protocol[15] Intertechno 433
Registering protocol[16] Mebus 433
Max number of protocols reached 15
Found 1 device(s):
 0: Generic, RTL2832U, SN: 77771111153705777
Using device 0: Generic RTL2832U
Found Rafael Micro R820T tuner
Exact sample rate is: 250000.000414 Hz
Sample rate set to 250000.
Sample rate decimation set to 0. 250000->250000
Bit detection level set to 10000.
Tuner gain set to Auto.
Reading samples in async mode...
Tuned to 433920000 Hz.

Energy Sensor CMR180 Id 6280 power: 240W, total: 508308384W, Total Energy: 141.196kWh
Weather Sensor THGR122N RC 86 Channel 1 Temp: 19.5°C 67.1°F Humidity: 46%
Energy Sensor cmr180 Id 6282 power: 272W
Sensor temperature event:
protocol = Rubicson/Auriol, 36 bits
rid = 1d
temp = 7.5
1d 80 4b f0 00 
Energy Sensor CMR180 Id 6280 power: 272W, total: 508323744W, Total Energy: 141.201kWh

Pour la réception à l’aide d’un arduino ou d’un raspberry pi, se reporter à mon post précédent https://blog.onlinux.fr/decode-and-parse-the-oregon-scientific-v3-radio-data-transmitted-by-owl-cm180-energy-sensor-433-92mhz-2/.